OPTIONS LS=80;
TITLE 'BREADWRAPPER DATA: MYERS, TABLE 3.1, LACK-OF-FIT';

DATA;
INPUT Y X1 X2 X3;
LOF=(100000*X1)+(100*X2)+X3;
DATALINES;
6.6 225 46 0.5
6.9 285 46 0.5
7.9 225 64 0.5
6.1 285 64 0.5
9.2 225 46 1.7
6.8 285 46 1.7
10.4 225 64 1.7
7.3 285 64 1.7
9.8 204.5 55 1.1
5.0 305.5 55 1.1
6.9 255 39.9 1.1
6.3 255 70.1 1.1
4.0 255 55 0.09 
8.6 255 55 2.11
10.1 255 55 1.1
9.9 255 55 1.1
12.2 255 55 1.1
9.7 255 55 1.1
9.7 255 55 1.1
9.6 255 55 1.1
;

PROC PRINT;

/* Method I starts here */

PROC GLM;
 MODEL Y= X1 X2 X3 X1*X1 X2*X2 X3*X3 X1*X2 X1*X3 X2*X3;
TITLE2 'COMPLETE SECOND ORDER RESPONSE SURFACE';

PROC GLM;
 CLASS LOF;
 MODEL Y=LOF;
TITLE2 'PURE ERROR CALCULATION';

/* Method I ends here*/

/* Method II starts here*/ 

PROC GLM;
 CLASS LOF;
 MODEL Y=X1 X2 X3 X1*X1 X2*X2 X3*X3 X1*X2 X1*X3 X2*X3 LOF;  
TITLE2 'USE OF PROC GLM FOR LOF TEST: FF-TEST FOR LOF IS LOF TEST';

/* Method II ends here*/ 

/* Method III starts here*/ 

PROC RSREG;
  MODEL Y=X1 X2 X3/LACKFIT;
TITLE2 'USE OF PROS RSREG FOR SECOND ORDER RESPONSE SUEFACE AND LOF TEST';

/* Method III ends here*/